
Runogeneraattorin kehittelyä

Mikko Eloholma
Tässä ohjeessa luomme yhdessä runogeneraattorin, joka valitsee jostakin aineistosta satunnaisia sanoja ja kirjoittaa niitä tietokoneen ruudulle. Pääset itse vaikuttamaan runokoneen käyttämään kirjalliseen aineistoon ja visuaaliseen ilmeeseen.
Tätä ohjetta ja Tekstipohjaista ohjelmointia Processing-ohjelmointiympäristössä -videota kannattaa käyttää rinnakkain. Videolla näytetään konkreettisesti useimmat ohjeen vaiheet.

Sisällys:
1. Millainen on runogeneraattori?
2. Tekstin käsittelyä
3. Sanojen arpominen listoista
4. Runogeneraattorin käyttäminen
5. Taustamaalauksen lisääminen
6. Runogeneraattorin viimeistely



[bookmark: _Toc90934298]

1. Millainen on runogeneraattori?
Alla on muutama esimerkki runogeneraattoreista, joita opettajat tekivät keväällä 2019 järjestetyllä avoimella Let Me Hack It -kurssilla. Kuvat ovat kuvakaappauksia, joten niihin ei ole valitettavasti taltioitu runojen arpomista.
Töiden taustoina toimivat kuvataiteen avoimista aineistoista valitut maalaukset, ja tekijät ovat myös valinneet sanat, joista tietokone runoja arpoo. Yhdessä työssä aineistona on netistä avoimesti ladattavissa oleva Kalevala!

	[image: Maisemakuva ja teksti "Kalmo hiljaa nauraa jo"]
Tekijä: Wilhelmiina Juhakoski
Maalaus: Elin Danielson-Gambog - Ruissalon silta (1891)
	[image: Kuvana aalto, tekstinä "matkalainen hamuaa raskaasti"]
Tekijä: Juha Vartiainen
Maalaus: Hokusai – Kanagawan Suuri aalto (n. 1830–1832)


	[image: Maisemakuva ja vene, tekstinä "empien löytää puro"]
Tekijä: Heidi Villikka
Maalaus: Utagawa Hiroshige – View of Late Spring at Masaki (1831)

	[image: Vene myrskyssä, tekstinä "hilarious shark dives many troubles"]
Tekijä: Bettiina Pikkarainen
Maalaus: Winslow Homer – The Gulf of Stream (1899)





[bookmark: _Toc90934299]2. Tekstin käsittelyä 
Aiemmassa ohjeessa tutustuit Processing-ympäristöön ja mahdollisesti loit elokuvajulisteen sekä toteutit sanataideteoksen, jossa tekstiä sijoitettiin myös satunnaisiin kohtiin piirtoikkunaa.
Nyt pääset luomaan runogeneraattoria. Aloitetaan hieman pohtimalla, mitä runogeneraattori toimiakseen vaatii.

Vaihe 1
Tähän mennessä olemme kirjoittaneet haluamamme tekstin text-komentoon lainausmerkkien sisään. Voimme tehdä mistä tahansa merkeistä tekstiä asettamalla ne lainausmerkkeihin – tällöin tietokone ymmärtää, että kyseesssä on vain merkkijono eikä esimerkiksi ohjelmointikomento.
Merkkijonojen eli tekstin tyyppi on Processingissa ja monissa muissakin ohjelmointikielissä String. 
· Kokeile seuraavaa koodia ja siirry eteenpäin ohjeissa!

// Luodaan String-tyypin muuttuja runo, joka sisältää tekstin "Olipa kerran vai oliko?".
String runo = "Olipa kerran vai oliko?";

void setup() {
size(600, 600);
}

void draw() {
textSize(40);
fill(255, 0, 255);
text(runo, 100, 100);
}

Vaihe 2
Edellä olevassa koodissa luotiin String-tyypin muuttuja, jonka nimi oli "runo" ja sisältö "Olipa kerran vai oliko?". Itse text-komennossa meidän tarvitsi viitata pelkästään tähän muuttujaan kirjoittamalla "runo". Siksi emme kirjoittaneet varsinaista tekstiä text-komennon parametriksi.
Muuttujat ovat ohjelmoinnissa eräänlaisia tietovarastoja. Muuttujat auttavat välttämään turhaa toistoa ja lyhentävät koodia.
· Seuraavaan koodiin on lisätty kaksi uutta muuttujaa. Kokeile koodia ja tutustu sen kommentteihin.

// Luodaan kolme String-tyypin muuttujaa: runo, runo2 ja runo3. Kaikki sisältävät eri sanan.
String runo = "Runoilen,";
String runo2 = "siis";
String runo3 = "olen";

void setup() {
size(600, 600);
}

void draw() {
textSize(40);
fill(255, 0, 255);

// Kirjoitetaan pätkä tekstiä kohtaan (100, 100)
// Kirjoitettava teksti on muuttujien runo, runo2 ja runo3 yhdistelmä. Näiden muuttujien tekstit siis kirjoitetaan peräjälkeen.
text(runo + runo2 + runo3, 100, 100);
}

Vaihe 3
Edellä olleessa koodissa luotiin kolme String-tyypin muuttujaa: runo, runo2 ja runo3. Kaikissa näissä oli oma sisältönsä. Text-komennossa nämä muuttujat yhdistettiin +-merkin avulla. Voit ketjuttaa sanoja ja kirjaimia tällä tapaa.
Koodissa oli kuitenkin eräs ongelma. Kaikki sanat olivat yhtä pötköä. Välilyönnit on helppo lisätä mukaan laittamalla ne kunkin sanan loppuun lainausmerkkien sisälle.
· Lisää mukaan välilyönnit ja piste alla olevan animaation tavoin.
[image: Havainnollistava animaatio välilyöntien lisäämisestä]

Lopuksi
Tällä sivulla opit luomaan String-tyypin muuttujia ja yhdistelemään niitä + -merkillä. Seuraavaksi luomme muuttujien sijaan listoja, joissa on useita sanoja. Näin pääset myös arpomaan sanoja listoista!

Edellä yhdistelit tekstiä String-tyyppisten muuttujien avulla. Seuraavaksi luomme sanoista listoja. Kun listassa on useita sanoja, näistä on helppo arpoa jokin sana ja kirjoittaa se piirtoikkunaan.

Vaihe 1
· Tutustu alla olevaan koodiin ja sen kommentteihin. Kokeile koodia.
· Vaihda sanat joiksikin toisiksi. Voit hakea inspiraatiota esimerkiksi suosikkikirjailijasi tuotannosta!
· Kun ymmärrät, miten voit valita listasta tietyn sanan ja kirjoittaa sen ruudulle, voit siirtyä eteenpäin.

// Luodaan sanoista koostuva lista. Annetaan nimeksi 'subjektit'.
// Listan ensimmäinen sana on 'minä', toinen on 'hanhi' jne.
String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};

void setup() {
size(600, 600);
frameRate(5);
}

void draw() {
textSize(40);
fill(255, 0, 255);
// Valitaan subjektit-listan ensimmäinen sana ja kirjoitetaan se piirtoikkunaan.
// Ensimmäinen sana valitaan lisäämällä indeksi 0 hakasulkujen sisään. Ohjelmoinnissa laskeminen aloitetaan aina nollasta!
text(subjektit[0], 100, 100);
fill(255, 255, 0);
// Valitaan listan toinen sana ja kirjoitetaan se piirtoikkunaan.
// subjektit[0] on listan ensimmäinen sana, ja toinen sana on siis subjektit[1]
text(subjektit[1], 100, 200);
}
Vaihe 2
Yllä olevassa koodissa luotiin lista sanoista. Listalla on muuttujan tavoin nimi ja sisältö. Erona muuttujaan on se, että lista voi sisältää useita sanoja. Voit viitata listan sanoihin kirjoittamalla listan nimen, ja lisäämällä hakasulkuihin indeksin. Tätä on havainnollistettu vielä oheisessa animaatiossa.
· Kun olet katsonut animaation, siirry eteenpäin ohjeissa.

[image: Animaatio, joka havainnollistaa listan käyttöä]

Vaihe 3
Osaat nyt luoda sanoista tehtyjä listoja ja valita näistä listoista sanoja, joita kirjoitetaan piirtoikkunaan. Hienoa! Runokoneen idea piilee kuitenkin siinä, että sanoja yhdistellään odottamattomalla ja hauskalla tavalla. Miten voisimme arpoa sanoista tehdystä listasta yhden sanan ja kirjoittaa sen piirtoikkunaan?
Muista, että voit viitata esimerkiksi subjektit-nimisen listan sanoihin kirjoittamalla subjektit[x], jossa x on valitsemasi sanan järjestysluku. Jos voisimme arpoa x:n arvon jokaisella kerralla uudestaan, saisimme tulostettua ruudulle satunnaisia sanoja listasta.
· Tutustu seuraavaan koodiin, jonka ideana on arpoa listasta satunnaisia sanoja. Koeta suorittaa koodi.
· Koodi antaa virheilmoituksen. Siirry eteenpäin ja selvitä, miksi!

// Luodaan sanoista koostuva lista, ja annetaan listan nimeksi 'subjektit'.
// Listan ensimmäinen sana subjektit[0] on 'minä'. Viimeinen sana subjektit[5] on 'tietokone'.

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};

void setup() {
size(600, 600);
frameRate(5);
}

void draw() {
textSize(40);
fill(255, 0, 255);

// Arvotaan luku väliltä 0-5 ja valitaan sillä satunnainen sana subjektit-listasta.
text(subjektit[random(0, 5)], 100, 100);
}

Vaihe 4
Yllä oleva koodi antaa virheilmoituksen "cannot convert from float to int".
Todella monissa ohjelmointikielistä löytyy kaksi yleistä numerotyyppiä, "float" ja "int". float viittaa desimaalilukuihin, kun taas int (integer) viittaa kokonaislukuihin. 
Koodi ei toimi, koska komento "random(0, 5)" arpoo desimaaliluvun väliltä 0–5. Luku voi olla esimerkiksi 3.523, ja kun yritämme käyttää tätä lukua valitaksemme tietyn sanan subjektit-listasta, tietokone menee solmuun ja antaa meille virheilmoituksen!
Meidän tulisi siis pyöristää random-komennon antama luku kokonaisluvuksi jollain tapaa. Onneksi tähän on olemassa helppo keino: int-komento pyöristää desimaaliluvun alaspäin lähimpään kokonaislukuun.
· Tutustu alla olevaan koodiin ja kokeile sitä.

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};

void setup() {
  size(600, 600); 
  frameRate(5);
}

void draw() {
 textSize(40);

 fill(255, 0, 255); 

 // Luodaan muuttuja 'sub', jonka tyyppi on int (integer eli kokonaisluku).
 // Tallennetaan muuttujaan 'sub' satunnaisluku väliltä 0-5. 
 // Satunnaisluku on desimaalimuotoinen, ja siitä tehdään kokonaisluku int-komennolla.
 // int-komento pyöristää desimaaliluvun alaspäin lähimpään kokonaislukuun.
 int sub = int(random(0, 5)); 

 // Valitaan sub-muuttujan avulla satunnainen sana listasta ja kirjoitetaan se satunnaiseen kohtaan.
 text(subjektit[sub], random(0, 600), random(0, 600));
}

Vaihe 5
Edellä oleva koodi toimii! Loimme siis kokonaislukumuuttujan nimeltään "sub", minkä jälkeen tallensimme siihen kokonaisluvuksi muuntamamme arvon.
· Tutustu alla oleviin koodiriveihin, jotka selventävät asiaa lisää.

// sub on nyt 3
int sub = int(3.523) ;

// sub on nyt 99
int sub = int(99.99);

// sub on nyt 0, 1, 2, 3 tai 4
int sub = int(random(0, 5));

int-komento pyöristää desimaaliluvun siis aina alaspäin. Jos arvomme luvun väliltä 0–5 ja pyöristämme sen alaspäin lähimpään kokonaislukuun, luku ei saa koskaan arvoa 5 ja listan viimeinen (kuudes) sana ei siis koskaan ilmesty ruudulle! Siksi luku kannattaa arpoa väliltä 0–6, jos listassa on kuusi sanaa.

Alla on korjattu koodi, joka arpoo minkä tahansa subjektit-listan sanan.
· Kirjoita koodi, joka arpoo sanoja omasta sanalistastasi. Jos sanalistassasi on eri määrä sanoja, täytyy sinun muokata myös random-komennon vaihteluväliä.

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};

void setup() {
  size(600, 600); 
  frameRate(5);
}

void draw() {
 textSize(40);
 fill(255, 0, 255); 

 // Luodaan kokonaislukumuuttuja 'sub' ja tallennetaan siihen satunnaisluku väliltä 0-6. 
 // Satunnaisluku on desimaalimuotoinen, ja siitä tehdään kokonaisluku pyöristämällä se alaspäin int-komennolla.
 int sub = int(random(0, 6)); 

 // Valitaan sub-muuttujan avulla satunnainen sana listasta ja kirjoitetaan se satunnaiseen kohtaan.
 text(subjektit[sub], random(0, 600), random(0, 600));
}

Vaihe 6
Lisätään mukaan vielä kaksi muuta sanalistaa, verbit ja adverbit.
· Valitse mieleisiäsi sanoja kumpaankin sanalistaan.
· Luo listoja varten omat kokonaislukumuuttujansa, joiden avulla listoista arvotaan sanat. 
· Säädä sanojen paikkoja siten, että ne ilmestyvät eri kohtiin piirtoikkunaa.

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};
String[] verbit = {"juoksee", "roikkuu", "pohtii", "hamuaa", "kaipaa", "etsii"};
String[] adverbit = {"kauniisti", "etsien", "jo", "yhä", "lopullisesti", "raskaasti"};

void setup() { 
 size(600, 600);
 frameRate(5);

}

void draw(){
 textSize(40);
 fill(255, 0, 255);
 int sub = int(random(0, 6)); 
 text(subjektit[sub], random(0, 600), random(0, 600));
 int ver = int(random(0, 6)); 
 text(verbit[ver], random(0, 600), random(0, 600));
 int adv = int(random(0, 6)); 
 text(adverbit[adv], random(0, 600), random(0, 600));
}
 
Lopuksi
Tässä osiossa opit luomaan sanoista listoja ja arpomaan sanoja näistä listoista piirtoikkunaan. 
Sanoja ilmestyi kuitenkin piirtoikkunaan jatkuvasti. Olisi parempi, jos voisimme hallita sanojen ilmestymistä esimerkiksi hiiren tai näppäimistömme avulla. Tätä siirrymme tekemään seuraavaksi.

Tähän mennessä luomamme ohjelma suorittaa komentojaan ulkomaailmasta välittämättä. Usein kuitenkin halutaan, että ohjelman kulkuun voisi vaikuttaa jollain tapaa esimerkiksi näppäimistön tai hiiren näppäimiä painamalla. 
Seuraavaksi teemme runogeneraattoristamme vuorovaikutteisen. Ohjelmoimme sen arpomaan uuden runon aina, kun hiirtä klikataan.

Vaihe 1
· Lisää generaattoriisi mukaan mouseClicked-metodi. Sen sisältö suoritetaan kerran aina silloin, kun hiirtä klikataan (painetaan pohjaan ja päästetään ylös).
· Siirrä sanoja arpovat osat mouseClicked-metodin sisään. Nyt uudet sanat kirjoitetaan ruudulle vain silloin, kun hiirtä klikataan!
· Suorita ohjelma ja kokeile sitä klikkailemalla hiirtäsi!

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};
String[] verbit = {"juoksee", "roikkuu", "pohtii", "hamuaa", "kaipaa", "etsii"};
String[] adverbit = {"kauniisti", "etsien", "jo", "yhä", "lopullisesti", "raskaasti"};

void setup() { 
 size(600, 600);
 frameRate(5);
}

void draw(){
 // Draw-osa on nyt aivan tyhjä. 
 // Tietokone suorittaa setup-osan jälkeen uusia komentoja vain silloin, kun hiirtä klikataan!
}

void mouseClicked(){

 // Nämä komennot suoritetaan aina kerran silloin, kun hiirtä klikataan.

 textSize(40);
 fill(255, 0, 255);
 int sub = int(random(0, 6)); 
 text(subjektit[sub], random(0, 600), random(0, 600));
 int ver = int(random(0, 6)); 
 text(verbit[ver], random(0, 600), random(0, 600));
 int adv = int(random(0, 6)); 
 text(adverbit[adv], random(0, 600), random(0, 600));
}

Vaihe 2
mouseClicked on setup- ja draw-osille rinnakkainen rakenne. Kun hiirtä klikataan, draw-osa keskeytyy ja tietokone suorittaa mouseClicked-metodin sisällä olevat komennot.
· Piirrä mouseClicked-metodin alussa taustanelikulmio haluamallasi värillä. Näin aiemmat ruudulla olevat asiat katoavat näkyvistä.
· Aseta taustanelikulmion piirtämisen jälkeen tekstille jokin sopiva väri. Jos et vaihda väriä taustanelikulmion piirtämisen jälkeen, teksti kirjoitetaan taustanelikulmion värillä, eikä se siksi näy ollenkaan!

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};
String[] verbit = {"juoksee", "roikkuu", "pohtii", "hamuaa", "kaipaa", "etsii"};
String[] adverbit = {"kauniisti", "etsien", "jo", "yhä", "lopullisesti", "raskaasti"};

void setup() { 
 size(600, 600);
 frameRate(5);
}

void draw(){
 // Draw-osa on nyt aivan tyhjä. 
 // Tietokone suorittaa setup-osan jälkeen uusia komentoja  vain silloin, kun hiirtä klikataan!
}



void mouseClicked(){
// Asetetaan taustanelikulmiota varten täyttöväriksi musta.
fill(0, 0, 0);
// Piirretään taustanelikulmio.
rect(0, 0, 600, 600);
textSize(40);
// Asetetaan tekstiä varten täyttöväriksi valkoinen.
fill(255, 255, 255);
 int sub = int(random(0, 6)); 
text(subjektit[sub], random(0, 600), random(0, 600));
 int ver = int(random(0, 6)); 
text(verbit[ver], random(0, 600), random(0, 600));
 int adv = int(random(0, 6)); 
text(adverbit[adv], random(0, 600), random(0, 600));
}

Vaihe 3
Sanojen paikat ovat tähän mennessä olleet satunnaisia.
· Aseta nyt sanoille tietyt paikat piirtoikkunassa siten, että ne muodostavat luettuna jonkinlaisen lauseen. Sanat voivat olla esimerkiksi peräkkäin tai allekkain.
· Lisää taustanelikulmion piirtäminen myös setup-osaan. Näin piirtoikkuna on oikean värinen jo silloin, kun ohjelma käynnistetään!

String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};
String[] verbit = {"juoksee", "roikkuu", "pohtii", "hamuaa", "kaipaa", "etsii"};
String[] adverbit = {"kauniisti", "etsien", "jo", "yhä", "lopullisesti", "raskaasti"};

void setup() { 
 size(600, 600);
 frameRate(5);
 // Piirretään taustanelikulmio heti ohjelman aluksi.
 fill(0, 0, 0);
 rect(0, 0, 600, 600);
}

void draw(){
}

void mouseClicked(){
 fill(0, 0, 0);
 rect(0, 0, 600, 600);
 textSize(40);
 fill(255, 255, 255);
 int sub = int(random(0, 6)); 

 // Subjekti ilmestyy kohtaan (300, 200)
 text(subjektit[sub], 300, 200);
 int ver = int(random(0, 6)); 

 // Verbi ilmestyy subjektin alle kohtaan (300, 250)
 text(verbit[ver], 300, 250);
 int adv = int(random(0, 6)); 

 // Adverbi ilmestyy verbin alle kohtaan (300, 300)
 text(adverbit[adv], 300, 300);
}

Lopuksi
Tässä osiossa opit tekemään generaattoristasi vuorovaikutteisen. Hiiren klikkaamisen lisäksi voit tarkkailla Processingissa esimerkiksi näppäimistösi painikkeita ja tietokoneen web-kameraa tai mikrofonia! Hiiren käyttäminen ei siis suinkaan ole ainoa mahdollinen vuorovaikutuksen tapa generaattorille – runo voitaisiin aivan yhtä hyvin arpoa silloin, kun läpsäytät käsiäsi tai asetat tietyn värisen esineen web-kameran eteen.
Edellä lisäsit generaattorillesi taustanelikulmion. Seuraavaksi pääset korvaamaan tämän taustanelikulmion taidemuseoiden avoimista aineistoista valitsemallasi maalauksella! Tämä luo tekstille kontekstin ja tekee generaattoristasi kokonaisvaltaisemman visuaalisen teoksen.

Viimeisessä vaiheessa pääset lisäämään runogeneraattorisi taustaksi maalauksen. Pääset etsimään juuri sinua kiinnostavan maalauksen taidemuseoiden avoimista aineistoista.
Kulttuuriperinnön luova käyttö ja digitaalinen muokkaus on tärkeä osa Maker-kulttuuria, kuten nähdään esimerkiksi Hack4FI 2018 -tapahtumassa tehdyistä projekteista. Taidemuseoiden avoimiin aineistoihin tutustuminen antaa paljon myös esimerkiksi taidehistorian oppitunneille. 
Jos maalaus sisältää henkilön, runo voi näyttäytyä puheena tai viestinä ja teos voi saada jopa sarjakuvamaisia tai meemimäisiä piirteitä. Maisemamaalauksen valitseminen taas voi johtaa enemmänkin abstraktin ja hartaamman tunnelman välittämiseen. 
Myös sanojen asettelu suhteessa maalaukseen vaikuttaa paljon siihen, miten runo tulkitaan. Siksi myös sanojen sijoitteluun piirtoikkunaan kannattaa keskittyä.
Ryhdytään hommiin!

Vaihe 1
Tutki yhdysvaltalaisen Metropolitan Museum of Artin digitaalista aineistoa, josta löydät tuhansia taideteoksia vuosisatojen ajalta. Käytä ylälaidan hakutoimintoa ja koeta löytää teos, joka voisi sopia runogeneraattorisi taustaksi.
Iso osa Metropolitanin töistä on julkaistu CC0-lisenssillä, jolloin niitä voi hyödyntää ja muokata täysin vapaasti. Alla olevassa animaatiossa on näytetty, miten voit etsiä taideteoksia ja nähdä niiden lisenssin.
Voit etsiä kuvia myös muiden taidemuseoiden aineistoista, kuten Europeanasta tai suomalaisesta Finnasta. Maalauksen paikallisuus tuo työhön aina omanlaistaan merkitystä.

[image: Metropolitan Museum of Artin digitaalisen aineiston hakua havainnollistava ruudunkaappausvideo]
Vaihe 2
Teosta etsiessä kannattaa pitää mielessä, että siitä tulisi löytyä jokin väljempi kohta (tai kohtia), johon sanat voisivat ilmestyä. Ja ehkä jokin teoksen tunnelmassa sopii juuri valitsemiisi sanoihin?
· Lataa itseäsi inspiroiva kuva tietokoneellesi. Nimeä kuva myöhempää käyttöä varten jollakin yksinkertaisella tavalla, esimerkiksi "tausta". 

[image: Taideteoksen kuvan tallentamista havainnollistava ruudunkaappaus]

Vaihe 3
Pääset kohta yhdistämään aiemmassa vaiheessa tekemäsi sanalistat ja kuvasi samaan teokseen, mutta luodaan ensin selkeyden vuoksi uusi tyhjä ohjelmaikkuna. 
· Avaa Processingissa tyhjä ikkuna (File > New).
· Tallenna työsi jollain nimellä (File > Save As), esim. "runogeneraattori". 
Tallennuksen oletussijaintina on luultavasti Processingin "Sketchbook", jonne luotiin nyt kansio työsi nimellä. Löydät Sketchbookin sijainnin kohdasta File > Preferences > Sketchbook Location.
Jotta kuvan lisääminen on mahdollista, täytyy meidän ensin siirtää valitsemasi maalaus Processingin ohjelmakansioon.
· Klikkaa Sketch > Add File ja etsi lataamasi kuva. Processing loi työsi kansioon Data-kansion ja kopioi kuvan sinne.
Kuvan ei vielä ole tarkoitus ilmestyä ruudulle, koska emme ole käyttäneet mitään ohjelmointikomentoja. Tätä pääset tekemään seuraavaksi.
[image: Kuvan tuominen Processingin ohjelmakansioon]

Vaihe 4
Lisää seuraavaksi kuva Processing-ohjelmasi taustaksi. Tämä hoituu kolmella komennolla, jotka löydät alla olevasta koodista.
1. Aivan ylälaidassa sinun tulee luoda PImage-tyypin objekti ja nimetä se.
2. Setup-osassa sinun pitää ladata tähän objektiin aiemmin valitsemasi kuva käyttämällä loadImage-komentoa.
· HUOM! Tarkista kuvatiedoston nimen kirjoitusasu ja kirjoita koodissa nimen perään myös tiedostotyyppi (esim. .jpg tai .png). Nimi pitää kirjoittaa tismalleen oikein, jotta koodi toimii. Alla olevassa animaatiossa on näytetty, miten näet tiedostopäätteen Windowsilla.
3. Lisää mouseClicked-osaan image-komento, joka piirtää kuvan ruudulle. Näin kuva lisätään ruudulle aina hiirtä klikattaessa.
[image: Kuvan tiedostopäätteen tarkistaminen]
// Luodaan PImage (Processing Image) -tyypin objekti ja annetaan sen nimeksi "tausta"
PImage tausta;

void setup() {
  size(600, 600);         
 // tarkista kuvatiedoston nimi koneellasi ja kirjoita se tismalleen samalla tavalla
  tausta = loadImage("tausta.jpg");
}

void draw() {
  // Draw-osa on toistaiseksi tyhjä. Kun ohjelma käynnistetään, suoritetaan setup kerran. 
  // Tämän jälkeen piirretään  asioita vain hiirtä klikattaessa. 
}

void mouseClicked(){
  // Piirretään objektiin 'tausta' tallennettu kuva. Kuvan vasen yläkulma tulee kohtaan (0, 0).
  image(tausta, 0, 0);       
}

Vaihe 5
Kuva on todennäköisesti liian suuri eikä sovi piirtoikkunaasi. Jos kuva on liian pieni, kannattaa valita toinen kuva, sillä kuvan suurentaminen heikentää sen laatua.
· Pienennä kuva, jos se on tarpeen. Pienentäminen on käyty läpi myös alla olevassa animaatiossa.
· Kuvaa on kätevintä pienentää jollakin kuvankäsittelyohjelmalla, esimerkiksi Paintilla. Katso ohjeet kuvan pienentämiseksi Paintin avulla.
· Toinen vaihtoehto on käyttää jotakin selainpohjaista työkalua (esim. Simple Image Resizer).
· Kun olet tehnyt kuvasta järkevämmän kokoisen, siirrä se Processing-ohjelmasi data-kansioon ja nimeä se jollakin yksinkertaisella tavalla. Voit korvata kuvalla vanhan vääränkokoisen kuvan.
· Suorita ohjelma uudestaan. Jos nyt puolestaan piirtoikkuna on väärän kokoinen, voit vaihtaa sen kokoa muuttamalla size-komennon parametrejä. Kuvan tarkan koon näet vilkaisemalla kuvan asetuksia.

[image: Kuvan pienentäminen Simple Image Resizerillä]

Vaihe 6
Lisätään seuraavaksi mukaan aiemmat sanoja arpovat osat! Nyt muodostuva ohjelma on samanlainen, jonka teit aiemmin. Nyt taustanelikulmion tilalla on vain valitsemasi kuva!
· Lisää ohjelman ylälaitaan komennot, joilla luodaan sanalistat.
· Lisää setup-osan loppuun image-komento, joka lisää kuvan ruudulle heti ohjelman aluksi.
· Lisää mouseClicked-osaan komennot, joilla arvotaan sanat ruudulle hiirtä klikattaessa.
· Muokkaa sanojen paikat sellaisiksi, että ne sopivat osaksi maalausta!

PImage tausta;

// Luodaan sanalistat.
String[] subjektit = {"minä", "hanhi", "hän", "ystävä", "automaatti", "tietokone"};
String[] verbit = {"juoksee", "roikkuu", "pohtii", "hamuaa", "kaipaa", "etsii"};
String[] adverbit = {"kauniisti", "etsien", "jo", "yhä", "lopullisesti", "raskaasti"};

void setup() {
size(568, 774);
tausta = loadImage("tausta.jpg");
// Lisätään kuva taustaksi heti alussa.
image(tausta, 0, 0);
}

void draw(){

}

void mouseClicked(){
image(tausta, 0, 0);
textSize(40);
// Arvotaan sanat piirtoikkunaan aina hiirtä klikattaessa.
int sub = int(random(0, 6));
fill(255);
text(subjektit[sub], 300, 200);
int ver = int(random(0, 6));
text(verbit[ver], 300, 250);
int adv = int(random(0, 6));
text(adverbit[adv], 300, 300);
}

Lopuksi
Lisäsit tässä osiossa maalauksen runogeneraattorisi taustaksi.
Seuraavaksi pääset vielä hiomaan generaattoriasi valitsemalla sanoille sommittelun, värit ja fontin. 


[bookmark: _Toc90934303]6. Runogeneraattorin viimeistely
Nyt pääset viimeistelemään runogeneraattorisi.

Vaihe 1
Valitse ensin kohdat, joihin sanat voisivat ilmestyä.
Voit luoda lisää sanalistoja teokseesi ja arpoa sanoja myös niistä. Sopiva sanojen määrä riippuu kuvasta ja sen tunnelmasta Alla on muutama kevään 2019 Let Me Hack It -opettajankoulutuksessa tehty sommitelma malliksi.

	[image: Maisemakuva ja vene, tekstinä "orava rakastaa yhä"]
	[image: Kuvana Yrjö VI:n muotokuva, tekstinä "Sanoi vanha Väinämöinen / tinaisista rinnuksista / Mi lienetki miehiäsi"]

	Tekijä: Milla Lohikainen 
Maalaus: Galjamin Valerian – Herttoniemi (1827)

	Tekijä: Teppo Harju
Maalaus: Sir William Beechey – George VI

	[image: Kaksi nuorta kovassa tuulessa, tekstinä "tuuli yhä rakastaa"]
	[image: Kuvana vesiputous, tekstinä "Väsymys kaduttaa nyt"]

	Tekijä: Piritta Honkanen
Maalaus: Pierre-Auguste Cot – The Storm (1880)
	Tekijä: Janne Koivuniemi
Maalaus: Tazaki Sōun – Yōrō Waterfall (1887)




Vaihe 2
Valitse sitten haluamasi fontti tekstille seuraamalla alta löytyviä ohjeita (ks. animaatio).
· Valitse Processingissa Tools > Create Font. 
· Valitse jokin fontti ja fonttikoko. Fonttikoko ei ole niin oleellinen, koska sitä voit vaihtaa myöhemmin textSize-komennolla.
· Valitse OK.
[image: Fontin vaihto]

Vaihe 3
Kun olet luonut fontin edellä olevilla ohjeilla, tulee sinun vielä kertoa tietokoneelle muutamalla ohjelmointikomennolla, että haluat käyttää kyseistä fonttia. Aloitetaan kopioimalla fontin nimi, jota tarvitset fontin lataamiseksi Processingiin (ks. animaatio).
· Mene ensin työsi data-kansioon, johon fontti on tallennettu. Kopioi fontin nimi siten, että tiedostopääte on mukana. 

[image: Fontin nimen kopiointi]

Vaihe 4
Kun olet kopioinut fontin nimen (edellinen vaihe), ota fontti käyttöön seuraamalla alla olevia ohjeita. Vaiheet on käyty läpi myös alla olevassa animaatiossa.
· Luo PFont-tyypin objekti ohjelman ylälaidassa.
· Tallenna setup-osassa tähän objektiin valitsemasi fontti loadFont-komennolla.
· HUOM! Fontin nimen on oltava täsmälleen oikein, jotta komento toimii! 
· Ota fontti vielä käyttöön textFont-komennolla.
· Muista, että voit vaihtaa tekstin väriä fill-komennolla.

[image: Fontin käyttöönotto Processingissa]
Vaihe 5
Tekstuaalista ja kuvallista ilmaisua yhdistäviä runoja olisi hauska jakaa muille kuvakaappauksien avulla!
· Lisää mouseClicked-metodin loppuun vielä komento saveFrame, joka tallentaa kuvakaappauksen työsi kansioon aina hiirtä klikattaessa.
· Löydät tallennetut kuvat siis tallentamasi Processing-työn kansiosta.

[image: Kuvakaappauksen tallentaminen]

Lopuksi
Onnittelut – olet nyt ohjelmoinut runogeneraattorin Processingilla! 



Tekijä: 
Eloholma, M. (2019). Piirrä, kirjoita, ohjelmoi! – Tutustuminen Processingin käyttöön. LUKILOKI-hanke 2018–2022. Jyväskylän yliopisto.
Sisällön on muokannut tämän dokumentin muotoon LUKILOKI-tiimi.

