
Piirrä, kirjoita, ohjelmoi! – Tutustuminen Processingin käyttöön

Mikko Eloholma

Tässä ohjeessa pääset tutustumaan Processing-ohjelmointiympäristöön ja jo hieman käsittelemään tekstiä sen avulla. 

Sisällys:
1. Piirrä ohjelmoiden
2. Kirjoita ohjelmoiden
3. Miten luoda liikettä?

1. Piirrä ohjelmoiden
Processing-ohjelmointi on pohjimmiltaan piirtämistä. Minkälaisia ohjeita tietokone sitten tarvitsee voidakseen piirtää jotakin?
Tietokoneelle täytyy ainakin kertoa, mitä piirretään. Piirrettävä asia voi olla esimerkiksi piste, viiva, ellipsi, kolmio tai neliö. Tämän lisäksi täytyy tarkentaa, mihin kohtaan asia piirretään. Saattaa olla paikallaan myös kertoa, minkä värinen, kokoinen tai paksuinen piirrettävä asia on.
Lähdetään liikkeelle piirtämällä erilaisia muotoja Processingin piirtoikkunaan! Opit ymmärtämään koordinaatistoa, joka luo pohjan kaikenlaisten asioiden piirtämiselle.

Vaihe 1
Avaa Processing-ohjelmointiympäristö. Alla on esitelty sen osat.
1. Editori. Tähän kirjoitat kaiken koodin.
2. Console. Tänne ilmestyvät ohjelman lähettämät viestit ja virheilmoitukset. Virheilmoitukset näkyvät punaisena paneelina, kuten kuvassa. Kuvan virheilmoitus johtuu siitä, että ellipse-koodirivin perästä puuttuu puolipiste (";").
3. Run- ja Stop-painikkeet. Ohjelma suoritetaan Run-napista ja pysäytetään Stop-napista.
4. Valikot. File-valikosta voit esimerkiksi tallentaa ohjelmasi ja löydät sieltä myös paljon kiinnostavia valmiita esimerkkejä. 
[image: Processingin ohjelmointinäkymä, johon on merkitty edellisessä listassa luetellut osat]

Vaihe 2
Aivan aluksi voit kopioida alta löytyvän ohjelman Processingin pääikkunaan eli editoriin. Ohjelmassa on kaksi osaa: setup ja draw. Setup-osassa on nyt yksi komento, size. Size-komennossa on kaksi numeroa (600 ja 600), joita kutsutaan parametreiksi.
· Kun ohjelmakoodi on editorissa, suorita se vasemman yläkulman kolmionmuotoisesta Run-painikkeesta.
· Kokeile muuttaa size-komennon parametrejä ja suorita ohjelma uudelleen aina muutoksen jälkeen. Mitä tapahtuu ja miksi?

void setup(){
size(600, 600);
}

void draw(){

}

Vaihe 3
Äskeinen ohjelma loi pelkästään tyhjän harmaan ikkunan. Miksi?
Ohjelmassa on kaksi erillistä rakennetta: setup ja draw. Setup suoritetaan aina kerran heti silloin, kun suoritat ohjelman painamalla Run-painiketta. Nyt setup-osassa oli vain yksi komento, "size", joka asetti piirtoikkunan kooksi 600 x 600 pikseliä.
Alla olevaan ohjelmaan on lisätty ensimmäinen kommentti ("// Asetetaan piirtoikkunan kooksi 600 x 600"). Kommentti on ihmiselle suunnattu muistiinpano, jonka tavoitteena on helpottaa ohjelman ymmärtämistä. Kommentti ei siis ole ohjelmointikomento. Processing-ympäristössä (ja monissa muissa ohjelmointikielissä) kommentti kirjoitetaan tekstinä kahden kauttaviivan jälkeen. Jatkossa koodiesimerkeissä on mukana kommentteja!
Kun setup on suoritettu kerran, siirrytään draw-osaan, jota suoritetaan aina uudestaan ja uudestaan. Draw-osa on kuitenkin vielä aivan tyhjä. Lisätään siihen ensimmäinen komento. 
· Lisää draw-osaan komento ellipse, kuten alla olevassa ohjelmassa. Suorita ohjelma.

void setup(){
// Asetetaan piirtoikkunan kooksi 600 x 600.
size(600, 600);
}

void draw(){
 
ellipse(300, 300, 50, 50);

}
Vaihe 4
Ruudun keskelle pitäisi ilmestyä pieni valkoinen ympyrä. Onneksi olkoon ensimmäisestä ohjelmastasi!
Ellipse-komennon sisälle asetettiin neljä parametriä: 300, 300, 50 ja 50. Vaihda ensin ellipse-komennon kahta ensimmäistä numeroa ja suorita ohjelma aina muutoksen jälkeen. Nämä numerot määrittävät ellipsin paikan. Jos käytät 600:n ylittäviä numeroita, ellipsi katoaa piirtoikkunalta.
Mutta miten paikka määritetään kahden numeron avulla?
· Open Processing -sivustolta löytyvässä esimerkissä voit hiirtäsi liikuttamalla koettaa päätellä, mikä on Processing-koordinaatiston logiikka. Siirry hieman esimerkkiä tutkittuasi eteenpäin!

Vaihe 5
Ellipsin paikka määritetään kahden numeron avulla luonnollisella tavalla: ensimmäinen numero on vaakasuuntainen koordinaatti ja toinen numero pystysuuntainen koordinaatti. Voidaan siis myös puhua x- ja y-suuntaisista koordinaateista.
Piste (0, 0) löytyy vasemmasta yläkulmasta. Kun liikutaan oikealle, vaakasuuntainen x-koordinaatti kasvaa. Aivan piirtoikkunan oikeassa laidassa tämä x-koordinaatti on 600 (piirtoikkunan leveys). Vastaavasti kun liikutaan alaspäin, pystysuuntainen y-koordinaatti kasvaa. Aivan piirtoikkunan alalaidassa y-koordinaatti on 600 (piirtoikkunan korkeus). 
· Muuta nyt ellipse-komennon kolmatta ja neljättä parametriä (alla 50 ja 50).
· Suorita ohjelma aina muutosten jälkeen ja koeta päätellä, mihin nämä numerot vaikuttavat.

void setup(){
// Asetetaan piirtoikkunan kooksi 600 x 600
size(600, 600);
}

void draw(){
// Piirretään ellipsi keskelle piirtoikkunaa.
ellipse(300, 300, 50, 50);
}

Vaihe 6
Kuten varmaan havaitsitkin, ellipse-komennon kaksi viimeistä parametriä vaikuttavat muodon leveyteen ja korkeuteen. Neljä parametriä määrittävät siis 1) vaakasuuntaisen paikan, 2) pystysuuntaisen paikan, 3) leveyden ja 4) korkeuden. Ilman näitä määritelmiä ellipsin piirtäminen olisikin vaikeaa!
Sinun ei jatkossa tarvitse selvittää kaikkien komentojen ja parametrien merkitystä kokeilemalla. Eri komentojen tiedot on listattu Processingin Reference-sivustolla. Sieltä löydät esimerkiksi ellipse-komennon dokumentaation.

	[bookmark: _Hlk90915332]Tietoruutu: Processing-ohjelmointiympäristö on suunniteltu visuaaliseen esittämiseen, ja se sisältää omat komennot kaikkien tavallisten muotojen piirtämiseen. Jos haluat, voit tutkia näitä komentoja Processingin Reference-sivulla kohdassa 2D Primitives.



Tästä eteenpäin aina, kun esitellään uusi ohjelmointikomento, tarjotaan samalla linkki komennon dokumentaatioon (katso esimerkiksi linkkinä näkyvä line-komento alla).
Ennen seuraavaan vaiheeseen siirtymistä kokeillaan vielä toista peruskomentoa nimeltään line. Line-komento piirtää nimensä mukaisesti viivan kahden pisteen välille.
· Kopioi alla oleva koodi ja suorita se. Koodin draw-osa sisältää nyt kaksi komentoa. Ensimmäinen piirtää ellipsin ja seuraava viivan. Viiva piirretään koodissa vasemmasta yläkulmasta (0, 0) oikeaan alakulmaan (600, 600).
· Kokeile piirtää viiva oikeasta yläkulmasta vasempaan alakulmaan.

void setup(){
// Asetetaan piirtoikkunan kooksi 600 x 600
size(600, 600);
}

void draw(){
// Piirretään 50 x 50 kokoinen ellipsi keskelle piirtoikkunaa.
ellipse(300, 300, 50, 50);
// Piirretään viiva pisteiden (0, 0) ja (600, 600) välille.
line(0, 0, 600, 600);
}

Vaihe 7

	Tietoruutu: Järjestyksellä on väliä! Tietokone lukee komennot aina ylhäältä alas yksi kerrallaan ja myös piirtää asiat siinä järjestyksessä. Line-komento on vasta ellipse-komennon jälkeen, ja siksi viiva on piirretty ellipsin päälle.



· Kokeile vielä lopuksi alla olevaa ohjelmaa, jossa ellipse- ja line-komennoilla on tehty yksinkertainen logo. Kokeile kirjoittaa oman nimesi alkukirjain line-komennoilla ellipsin sisään.
· Voit halutessasi tallentaa ohjelmasi klikkaamalla Processingissa File > Save As. Anna sille jokin kuvaava nimi. 

void setup() {
size(600, 600);
}

void draw() {
ellipse(300, 300, 400, 400);
// Piirretään kirjain 'Z' ellipsin sisälle kolmella viivalla.
line(200, 200, 400, 200);
line(400, 200, 200, 400);
line(200, 400, 400, 400);
}

Lopuksi
Tässä osiossa olet oppinut ohjelmoimaan perustavanlaatuisia geometrisia muotoja. Loppujen lopuksi kaikki kuvat koostuvat erilaisista muodoista, jotka loppujen lopuksi koostuvat pisteistä. Meidän ei kuitenkaan onneksi tarvitse ohjelmoida kaikkia kuvia ja kirjaimia piste tai muoto kerrallaan.
Seuraavassa osiossa otamme käyttöön text-toiminnon, jolla voit kirjoittaa ruudulle tekstiä.



[bookmark: _Toc90934573]2. Kirjoita ohjelmoiden
Kaikki tietokoneen tuottamat visuaaliset asiat koostuvat lopulta pikseleistä, eli aivan pienistä jonkin värisistä pisteistä. Esimerkiksi juuri nyt lukemasi tekstin kirjaimet muodostuvat pienistä mustista pisteistä.

[image: GIF-animaatio, joka havainnollistaa kirjainten koostumista pikseleistä]

Meidän ei kuitenkaan onneksi tarvitse ohjelmoida kaikkia visuaalisia asioita pikseli kerrallaan. Esimerkiksi ellipse-komennolla voit automaattisesti piirtää joukon pisteitä, jotka näyttävät pyöreältä muodolta.
Edellisen sivun lopussa hahmottelit kirjaimia line-komennoilla. Seuraavaksi tutustumme text-komentoon, jolla voit helpommin kirjoittaa piirtoikkunaan haluamaasi tekstiä.

Vaihe 1
· Suorita alla oleva koodi, joka kirjoittaa tekstin keskelle piirtoikkunaa.
· Muuta teksti haluamaksesi.
· Vaihda tekstin paikkaa muuttamalla text-komennon kahta viimeistä parametriä. Nämä numerot määrittävät tekstin paikan koordinaatteina, aivan kuin ellipsejäkin piirtäessä. Koordinaatit määrittävät tekstilaatikon vasemman yläkulman koordinaatit, joten teksti ilmestyy pisteen alapuolelle ja jatkuu siitä oikealle.
 
void setup(){
size(600, 600);
}

void draw(){
// Piirretään teksti "Onko tämä runo?" piirtoikkunaan.
// Tekstilaatikon vasen yläkulma on kohdassa (300, 300) eli ruudun keskellä.
text("Onko tämä runo?", 300, 300);
}
 
Vaihe 2
Teksti on vielä aivan liian pientä. 
· Vaihda tekstin koko sopivaksi textSize-komennolla, kuten alla olevassa koodissa.
· Kirjoita ruudulle myös jokin muu sana sopivaan kohtaan.
· Huomaa, että voit kirjoittaa eri sanat eri kokoisina! Asettamasi tekstin koko on voimassa aina siihen asti, kun määrität tekstin koon uudestaan.

void setup(){
size(600, 600);
}

void draw(){
// Asetetaan tekstin kooksi 50.
textSize(50);
text("Onko tämä runo?", 100, 100);
// Asetetaan tekstin kooksi 30.
textSize(30);
text("Kyllä/Ei?", 230, 200);
}

Vaihe 3
Emme ole vielä vaihtaneet piirtovärejä. Tietokoneympäristöissä värit jaotellaan usein piirtoviivan väriin (stroke) ja täyttöväriin (fill). Täyttöväri on ollut oletuksena valkoinen, ja siksi sekä ellipsit että teksti ovat olleet tämän värisiä. Piirtoviivan väri on ollut oletuksena musta, ja siksi viivat ja ellipsin ääriviivat olivat edellisellä sivulla mustia.

[image: Esimerkkikuva ellipsistä ja viivasta.]

Tekstin väriä vaihdetaan fill-komennolla. Värit on määritetty RGB-värikoodeilla, eli kolme numeroa kuvaavat värien punaisuuden, vihreyden ja sinisyyden määrät. Arvojen tulee olla väliltä 0–255. Esimerkiksi:
fill(255, 0, 0); tekee täyttöväristä punaisen.
fill(0, 255, 0); tekee täyttöväristä vihreän.
fill(0, 0, 255); tekee täyttöväristä sinisen.
fill(120, 182, 84); tekee täyttöväristä metsänvihreän.

· Lisää koodiisi fill-komento ja kokeile jotakin väriä kirjoittamalla kolme parametriä komennon sisään, kuten alla.
· Valitse lopulta jokin osuva väri tekstillesi.

void setup(){
size(600, 600);
}

void draw(){
// Asetetaan väriksi liila. Punainen ja sininen arvo ovat maksimissaan (255) ja vihreä arvo on minimissään (0).
fill(255, 0, 255);
textSize(100);
text("Onko tämä runo?", 100, 100);
textSize(50);
text("Kyllä/Ei?", 230, 200);
}

Vaihe 4
Voit harjoitella tähän mennessä opittuja taitoja suunnittelemalla oman elokuvajulisteen. Alla on eräs esimerkki julisteen piirtävästä koodista. Julisteen tekemisessä on käytetty myös nelikulmion piirtävää rect-komentoa. Kommentit selventävät koodia!
· Suunnittele elokuvajuliste, joka koostuu muutamasta muodosta ja sanasta. Muista, että voit vaihtaa tekstin kokoa ja värejä kesken ohjelman. 

void setup(){
//Asetetaan piirtoikkunan kooksi 500 x 600 pikseliä
size(500, 600);
}

void draw(){
// Asetetaan täyttöväriksi musta
fill(0);
// Piirretään nelikulmio, jonka vasen yläkulma on pisteessä (0, 0) ja koko on 500 x 600
// Näin nelikulmio peittää koko piirtoikkunan
rect(0, 0, 500, 600);
// Asetetaan tekstin kooksi 50
textSize(50);
// Asetetaan täyttöväriksi liila
fill(250, 0, 250);
// Kirjoitetaan teksti piirtoikkunaan
text("Avaruusseikkailu", 30, 60);
// Asetetaan tekstin kooksi 100
textSize(100);
// Kirjoitetaan teksti piirtoikkunaan
text("2019", 30, 150);
// Asetetaan täyttöväriksi valkoinen
fill(255, 255, 255);
// Piirretään ellipsi kohtaan (400, 400). Ellipsin koko on 350 x 350
ellipse(400, 400, 350, 350);
// Asetetaan täyttöväriksi turkoosi
fill(0, 255, 255);
// Piirretään avaruusalusta esittävä pieni nelikulmio kohtaan (100, 300)
rect(100, 300, 50, 10);
}
 
Lopuksi
Tässä osiossa opit kirjoittamaan tekstiä piirtoikkunaan. Opit myös vaihtamaan tekstin kokoa ja väriä. 
Tähän mennessä kaikki piirtoikkunalla olevat asiat ovat olleet paikoillaan. Seuraavaksi lähdemme luomaan piirtoikkunaan liikettä ja vaihtelua!


[bookmark: _Toc90934574]3. Miten luoda liikettä?
Tietokoneohjelmat koostuvat yleensä komennoista, joita toistetaan yhä uudestaan ja uudestaan.
Alla on kuva lyhyestä Scratch-ohjelmasta. Siinä siniset ohjelmointikomennot ("move 20 steps" ja "turn 15 degrees to left") ovat forever-rakenteen sisällä. Niitä siis toistetaan ikuisesti! Kun forever-rakenteen sisällä oleva viimeinen komento ("turn 15 degrees to left") on suoritettu, palataan taas ensimmäiseen komentoon ("move 20 steps"). Forever-rakenne on siis eräänlainen silmukka!
[image: Scratch-sovelluksen forever-rakenne]

Processing-ympäristössä tietokone suorittaa yhä uudestaan ja uudestaan ohjelman draw-osaa. Olemme jo kirjoittaneet paljon erilaisia komentoja draw-osaan. Piirtoikkunaan ilmestyvät asiat eivät kuitenkaan ole vielä liikkuneet. Osaatko sanoa miksi?
Lähdetään tutkimaan, miten voisimme tuoda piirtoikkunaan vaihtelua ja liikettä. Tämä on välttämätöntä runogeneraattorinkin luomisen kannalta: jos mikään ruudulla ei muutu, ei kyseessä ole kummoinen runokone.

Vaihe 1
Palataan koodiin, joka piirtää näytölle vain yhden sanan.
· Korvaa sanan x-suuntainen paikka random-komennolla alla olevaan tapaan. Suorita ohjelma.
· Vaihda sitten random-komennon kahta parametriä, jotka alla olevassa koodissa ovat 0 ja 600.
· Pohdi, miten nämä numerot vaikuttavat lopputulokseen.

void setup(){
size(600, 600);
}

void draw(){
textSize(50);
fill(250, 0, 250);
text("YEAH!", random(0, 600), 250);
}

Vaihe 2
Random-komentoa voidaan nimensä mukaisesti käyttää lukujen arpomiseen. Äskeisessä esimerkissä tietokone arpoi tekstille uuden vaakasuuntaisen sijainnin aina, kun draw-osa suoritettiin. Random-komennon perässä olevat kaksi parametriä määrittävät sen, miltä väliltä numero arvotaan. Jos luvut ovat 0 ja 600, tekstin vaakasuuntainen sijainti arvotaan koko piirtoikkunan leveydeltä.
· Aseta nyt myös tekstin pystysuuntaisen paikan tilalle random-komento. Kokeile eri vaihteluvälejä!

void setup(){
size(600, 600);
}

void draw(){
textSize(50);
fill(250, 0, 250);
// Piirretään teksti, jonka vaaka- ja pystysuuntaiset paikat ovat satunnaisia lukuja väliltä 0-600.
text("YEAH!", random(0, 600), random(0, 600));
}
 
Vaihe 3
Voit käyttää random-komentoa missä yhteydessä tahansa!
· Aseta vielä lopuksi tekstin koko satunnaiseksi asettamalla random-komento textSize-komennon sisään.
· Pohdi sopiva vaihteluväli tekstin koolle. Mikä on pienin tekstikoko, jota vielä pystyt lukemaan, ja mikä on suurin tekstikoko, joka vielä jotenkin sopii piirtoikkunaan?

void setup(){
size(600, 600);
}

void draw(){
// Arvotaan tekstin koko väliltä 5-100.
textSize(random(5, 100));
fill(250, 0, 250);
text("YEAH!", random(0, 500), random(0, 500));
}
Vaihe 4
Tämän osion koodeissa sanoja on ilmestynyt ruutuun todella nopeaa tahtia. Olisi hyvä, jos voisimme hieman hidastaa ohjelman suoritusnopeutta.
· Aseta Setup-osaan frameRate-komento, jolla voit vaikuttaa draw-osan suoritusnopeuteen. 
· Kokeile eri frameRate-arvoja.

void setup(){
size(600, 600);
// Asetetaan draw-osan suoritusnopeudeksi viisi kertaa sekunnissa
frameRate(5);
}

void draw(){
textSize(random(5, 100));
fill(250, 0, 250);
text("YEAH!", random(0, 500), random(0, 500));
}

Vaihe 5
· Piirrä teoksellesi taustanelikulmio. Nelikulmio piirretään rect-komennolla alla olevaan tapaan. Huomaa, että nelikulmiota piirrettäessä määritetään aina nelikulmion vasemman yläkulman paikka.
· Aseta nelikulmiolle haluamasi väri.

void setup(){
size(600, 600);
frameRate(5);
}

void draw(){
// Asetetaan taustanelikulmiota varten täyttöväriksi musta
fill(0, 0, 0);
// Piirretään taustanelikulmio.
// Nelikulmion vasen yläkulma on pisteessä (0, 0) ja nelikulmion koko on 600 x 600
rect(0, 0, 600, 600);
textSize(random(5, 100));
fill(250, 0, 250);
text("YEAH!", random(0, 500), random(0, 500));
}

Vaihe 6
Taustanelikulmio piirretään aina draw-osan aluksi. Se peittää aina kaiken aiemmin piirretyn, ja siksi näkyvillä on vain yksi sana kerrallaan.
Mutta eikö olisi mielenkiintoista, jos aiemmat piirtoikkunan asiat häipyisivät näkyvistä vähitellen? Tehdään viimeiseksi tämän kaltainen häivytysefekti. Täyttöväristä saa osittain läpinäkyvän, kun lisää fill-komentoon neljännen parametrin. Jos tämä arvo on 0, väri on täysin läpinäkyvä eikä täyttöväriä siis edes ole. Jos arvo on 255, väri ei ole lainkaan läpinäkyvä.
· Aseta taustanelikulmion täyttöväri osittain läpinäkyväksi lisäämällä fill-komentoon neljäs parametri.
· Läpinäkyvyyttä osoittavan parametrin tulee olla väliltä 0–255. Kokeile sopivaa arvoa!

Katso havainnollistava animaatio, jossa kokeillaan eri läpinäkyvyysarvoja taustanelikulmiolle.

[image: Läpinäkyvyyttä havainnollistava animaatio]

Harjoitus: Sanataideteos
Voit kokeilla tehdä tämän osion työkaluilla sanataideteoksen. Teoksen teemana voi olla esimerkiksi talvi – tai mikä tahansa valitsemasi aihe. Etene seuraavasti:
· Valitse jokin yksinkertainen huudahdus, sana, kysymys tai lause ja sijoita se text-komennon sisään.
· Aseta tekstin paikka ja koko satunnaiseksi random-komennoilla.
· Aseta tekstille jokin teemaan sopiva väri. Voit halutessasi tehdä myös väristä satunnaisen: sijoita tällöin random-komentoja myös fill-komennon sisään.
· Piirrä valitsemasi värinen taustanelikulmio, joka häivyttää tekstiä vähitellen.

Lopuksi
Tässä osiossa opit luomaan piirtoikkunaan vaihtelua käyttämällä random-komentoa. Random-komennon luoma liike on satunnaista. Usein ohjelmoimalla halutaan animoida jatkuvaa liikettä (esimerkiksi hahmon käveleminen), mutta siihen emme perehdy tällä opintojaksolla.
Tässä ohjeessa olet harjoitellut muotojen ja tekstin sijoittamista piirtoikkunaan ja saanut yleiskäsityksen Processing-ohjelmointiympäristön käytöstä ja toiminnasta. Seuraavassa ohjeessa perehdytään Processingiin vielä tarkemmin ja toteutetaan runogeneraattorin. Se voi olla myös palautettava tehtäväsi tällä opintojaksolla.  

